/* ----------------------------------------------------------------------- */
/* Script, ou programme, Stata illustrant l'Exercice 2 de la section Polys */
/* ----------------------------------------------------------------------- */

/* lecture des données, préciser le chemin ou définir le répertoire si nécessaire */
use "aviation.dta", clear

/* création des nouvelles variables pour traiter par les mco le modèle linéarisé */
/* gener ou gen */
gen lq=ln(q)
gen ll=ln(l)
gen lk=ln(k)

/* estimation du modèle de base */
/* regress ou reg */
reg lq ll lk

/* pour se souvenir de tous les résultats disponibles après une régression */
ereturn list

/* pour archiver la somme des carrés des résidus, qui servira plus tard */
/* scalar ou scal */
scal scr0=e(rss)

/* pour voir et vérifier */
/* display ou disp */
disp(scr0)

/* estimation du modèle contraint (pas indispensable, juste pour voir la procédure) */
constraint define 1 ll+lk=1
cnsreg lq ll lk, constraints(1)

/* création des variables pour estimer le modèle transformé */
gen lql=lq-ll
gen lkl=lk-ll

/* estimation du modèle transformé */
reg lql ll lkl

/* création de la dummy variable notant le caractère "privé" d'une compagnie */
gen dpub=(pp=="publique")

/* estimation du modèle avec la dummy variable */
reg lq ll lk dpub

/* variante avec création automatique de la dummy variable via la commande xi */
xi : reg lq ll lk i.pp

/* régressions séparées avec archivage de la somme des carrés des résidus */
reg lq ll lk if dpub==1
scal scr1=e(rss)
reg lq ll lk if dpub==0
scal scr2=e(rss)

/* calcul de la quantité permettant le test de Chow */
disp(scr0)
disp(scr1)
disp(scr2)
scal chow=((scr0-(scr1+scr2))/3)/((scr1+scr2)/44)
disp(chow)

/* test de Chow à l'aide de la distribution de Fisher appropriée */
disp(Ftail(3,44,chow))